Реклама на сайте | Помощь сайту   English version | Free likes 
KAZUS.RU - Электронный портал. Принципиальные схемы, Datasheets, Форум по электронике

Типовая схема подключения LCD-модуля к микроконтроллерам MCS-51

Типовая схема подключения LCD-модуля к микроконтроллерам MCS-51



Раздел: Оптоэлектроника

Фирма Ineltek предлагает широкий выбор жидкокристаллических индикаторов различных типов. Большой популярностью у специалистов пользуются алфавитно-цифровые ЖКИ-модули на базе контроллера HD44780 фирмы Hitachi или его аналогов производства других фирм: Epson, Philips, Samsung, Sanyo, Toshiba .

Контроллер HD44780 допускает подключение к микропроцессорам по четырёх битному или восьми битному интерфейсу. Выбор интерфейса производится пользователем исходя из ограничений на время, затрачиваемое на обмен данными с котроллером, или количество используемых линий подключения к микро-ЭВМ.

Специалистами фирмы применялись различные схемы подключения алфавитно-цифровых ЖКИ-модулей к микрo-ЭВМ семейства AT89C2051 фирмы Atmel. На Рис.1 представлена схема подключения ЖКИ-модуля на базе контроллера HD44780 к микро-ЭВМ семейства MCS51 в режиме работы с внешней памятью, позволяющая оптимизировать процесс обмена данными по времени. Пересылка байта осуществляется по командам:

MOVX A,@DPTR или MOVX A,@DPTR.

В этом случае в DPTR следует загружать адрес с учётом того, что младший бит А0 будет обозначать направление передачи (запись/чтение), а бит А1 тип передаваемой информации (команда/данные).

Ниже приведены исходные тексты подпрограммы на языке ассемблера ASM51, позволяющие записывать данные, инструкции в контроллер, считывать данные. Приведен так же примерный текст подпрограммы инициализации контроллера в режим восьми битного интерфейса, при работе с двумя строками. Отображение курсора и мигание отключено. Курсор установлен в начало первой (верхней) строки.

	
WRC_LC   EQU ХХХ0H	
RDC_LC   EQU ХХХ1H
WRD_LC   EQU ХХХ2H
RDD_LC   EQU ХХХ3H

;ИНИЦИАЛИЗАЦИЯ HD44780

LCDINIT: MOV   A,#38H   ; 8-BIT 2-LINES
         ACALL WRC
         MOV   A,#0CH   ; DISP-ON, CUR-OFF, FLASH-OFF
         ACALL WRC
         MOV   A,#06H   ; MOVE CURSOR RIGHT
         ACALL WRC
CLS:     MOV   A,#01H   ; CLEAR SCREEN
         ACALL WRC
         RET

;ЧТЕНИЕ ДАННЫХ ИЗ HD44780 В ACC

RDD_LCD: MOV   DPTR,#(RDC_LC)
WAITDD:  MOVX  A,@DPTR
         JB    ACC.7,WAITDD
         MOV   DPTR,#(RDD_LC)
         MOVX  A,@DPTR
         RET 

;ЗАПИСЬ ДАННЫХ В HD44780 ИЗ АСС

WRD:     PUSH  ACC
         MOV   DPTR,#(RDC_LC)
WAITRD:  MOVX  A,@DPTR	        ;ОЖИДАНИЕ 
         JB    ACC.7,WAITRD    ;ГОТОВНОСТИ
         MOV   DPTR,#(WRD_LC)
         POP   ACC
         MOVX  @DPTR,A
         RET 

;ЗАПИСЬ КОМАНДЫ В HD44780 ИЗ АСС

WRC:     PUSH  ACC
         MOV   DPTR,#(RDC_LC)
WAITRC:  MOVX  A,@DPTR	        ;ОЖИДАНИЕ 
         JB    ACC.7,WAITRC    ;ГОТОВНОСТИ 
         POP   ACC
         MOV   DPTR,#(WRC_LC)
         MOVX  @DPTR,A
         RET

При использовании данных подпрограмм изменяется содержимое DPTR. Если там находится необходимая в дальнейшем информация, то для её сохранения достаточно воспользоваться стеком.

Надеемся, что приведённая примеры позволят Вам сэкономить время на освоении ЖКИ-модулeй с контроллерами, совместимыми с HD44780.


Источник: gaw.ru
Работа в москве охрана объектов. || Чугунные ванны и комплектующие с доставкой по адресу на сайте udarnik || https://otdelka4u.ru || https://prodentconcept.com сколько стоит установка керамических брекетов в москве. || Самая актуальная информация газоблок псков у нас.
 © 2003—2024 «Электронный портал»Обр@тная связь